main.cpp

查看本檔案說明文件.

 
#include "BluetoothSerial.h"
#include <driver/i2s.h>
 
#define I2S_SCK 26
#define I2S_WS 25
#define I2S_IN 23
#define LED 2
#define I2S_PORT I2S_NUM_0
#define I2S_SAMPLE_RATE     (16000)
#define I2S_SAMPLE_BITS     (16 * 2)
#define I2S_READ_LEN        (16 * 1024)
#define MU 255.0f
 
BluetoothSerial SerialBT;
bool isRecording = false;
bool i2sActive = false;
char* i2s_read_buff;
uint8_t* flash_write_buff;
 
TaskHandle_t taskHandler = NULL;

inline int16_t compress_log12(int16_t sample) {
    float x = (float)sample / 32768.0f;
 
    float y = copysignf(log1pf(MU * fabsf(x)) / log1pf(MU), x);
 
    int log12 = (int)(y * 2047.0f);
 
    if (log12 > 2047) log12 = 2047;
    if (log12 < -2047) log12 = -2047;
 
    return (int16_t)log12;
}

inline uint8_t compress_log4(int16_t sample) {
    float x = fabsf((float)sample) / 32768.0f;
 
    float y = log1pf(MU * x) / log1pf(MU);
 
    int log4 = (int)(y * 15.0f + 0.5f);
    if (log4 > 15) log4 = 15;
 
    return (uint8_t)log4;
}

void i2sInit() {
    i2s_config_t i2s_config = {
        .mode = (i2s_mode_t)(I2S_MODE_MASTER | I2S_MODE_RX),
        .sample_rate = I2S_SAMPLE_RATE,
        .bits_per_sample = i2s_bits_per_sample_t(I2S_SAMPLE_BITS),
        .channel_format = I2S_CHANNEL_FMT_RIGHT_LEFT,
        .communication_format = I2S_COMM_FORMAT_STAND_I2S,
        .intr_alloc_flags = 0,
        .dma_buf_count = 8,
        .dma_buf_len = 64,
        .use_apll = 1
    };
 
    i2s_driver_install(I2S_PORT, &i2s_config, 0, NULL);
 
    const i2s_pin_config_t pin_config = {
        .bck_io_num = I2S_SCK,
        .ws_io_num = I2S_WS,
        .data_out_num = -1,
        .data_in_num = I2S_IN
    };
 
    i2s_set_pin(I2S_PORT, &pin_config);
}

void i2s_adc(void *arg) {
    size_t bytes_read;
 
    while (1) {
        i2s_read(I2S_PORT, (void*) i2s_read_buff, I2S_READ_LEN, &bytes_read, portMAX_DELAY);
 
        if (isRecording) {
            int32_t* buffer32 = (int32_t*)i2s_read_buff;
            int samples = bytes_read / sizeof(int32_t);
 
            int j = 0;
            for (int i = 0; i < samples; i+=2) {
                int16_t left  = buffer32[i] >> 16;
                int16_t right = buffer32[i + 1] >> 16;
 
                int16_t left12 = compress_log12(left);
                uint8_t right4 = compress_log4(right);
 
                flash_write_buff[j++] = left12 & 0xFF;
                flash_write_buff[j++] = ((left12 >> 8) & 0x0F) | (right4 << 4);
            }
 
            SerialBT.write((const byte*) flash_write_buff, j);
        } else {
            vTaskDelay(10 / portTICK_PERIOD_MS);
        }
    }
 
    vTaskDelete(NULL);
}

void i2sTask(void *pvParameters) {
    while (true) {
        if (i2sActive) {
            Serial.println("I2S Initialized!");
            i2sInit();
            xTaskCreate(i2s_adc, "i2s_adc", 2048, NULL, 1, &taskHandler);
            while (i2sActive) {
                vTaskDelay(100 / portTICK_PERIOD_MS);
            }
            Serial.println("I2S released!");
            i2s_driver_uninstall(I2S_PORT);
            vTaskDelete(taskHandler);
        } else {
            vTaskDelay(100 / portTICK_PERIOD_MS);
        }
    }
}

void startRecording() {
    Serial.println(" *** Recording Start ***");
    digitalWrite(LED, HIGH);
    isRecording = true;
}

void finishRecording() {
    if (!isRecording) return;
 
    Serial.println(" *** Recording End ***");
    digitalWrite(LED, LOW);
    isRecording = false;
}

void resetFlags() {
    isRecording = false;
    i2sActive = false;
}

void btCallback(esp_spp_cb_event_t event, esp_spp_cb_param_t *param) {
    if (event == ESP_SPP_SRV_OPEN_EVT) {
        Serial.println("Client Connected!");
        esp_bt_gap_set_scan_mode(ESP_BT_CONNECTABLE, ESP_BT_NON_DISCOVERABLE);
        i2sActive = true;
    } 
    else if (event == ESP_SPP_DATA_IND_EVT) {
        Serial.printf("ESP_SPP_DATA_IND_EVT len=%d handle=%d\n", param->data_ind.len, param->data_ind.handle);
 
        if (param->data_ind.len > 0) {
            int dataLen = param->data_ind.len;
            char textArray[dataLen + 1];
            strncpy(textArray, (const char*)param->data_ind.data, dataLen);
            textArray[dataLen] = '\0';
            String textString = textArray;
            textString.trim();
 
            Serial.printf("*** Text String: %s\n", textString.c_str());
 
            if (textString.equals("START")) {
                startRecording();
            }
            else if (textString.equals("STOP")) {
                finishRecording();
            }
        }
    }
    else if (event == ESP_SPP_CLOSE_EVT){
        Serial.println("Client Disconnected!");
        esp_bt_gap_set_scan_mode(ESP_BT_CONNECTABLE, ESP_BT_GENERAL_DISCOVERABLE);
        resetFlags();
    }
}

void initBT(const char* name = "Recorder") {
    if (!SerialBT.begin(name)) {
        Serial.println("An error occurred initializing Bluetooth");
        ESP.restart();
        return;
    }
 
    Serial.printf("Bluetooth Initialized (%s)\n", name);
    SerialBT.register_callback(btCallback);
    Serial.println("======================================================");
    Serial.printf("Device '%s' started, now you can pair it with Bluetooth\n", name);
    Serial.println("======================================================");
}

void setup() {
    Serial.begin(115200);
    pinMode(LED, OUTPUT);
    digitalWrite(LED, LOW);
 
    i2s_read_buff = (char*) calloc(I2S_READ_LEN, sizeof(char));
    flash_write_buff = (uint8_t*) calloc(I2S_READ_LEN, sizeof(char));
 
    initBT("Recorder");  // 想改藍牙名稱可以改這裡
    xTaskCreate(i2sTask, "I2S Task", 4096, NULL, 1, NULL);
}
 
void loop(){
 
}